
// -------------------------- PROGRAMMA GESTIONE TRENI PUNTO A PUNTO (PaP) -----------------------------

// ------------------------- Dichiarazione Librerie, costanti, Pin, Variabili --------------------------

const int psens_sta = 2;      // pin D02 sensore stazione
const int psens_mag = 3;      // pin D03 sensore magazzino 
const int psens_end = 4;      // pin D04 sensore fine corsa
const int psens_seg = 5;      // pin D05 sensore sgnale
const int psens_vel = 18;     // pin A4  sensore velocità

const int pvoic_cam = 14;     // pin A0  suono campanella filo bianco connettori blu gnd e collettore verdi segnale
const int pvoic_par = 15;     // pin A1  suono partenza filo viola
const int pvoic_arr = 16;     // pin A2  suono arrivo filo verde
const int pvoic_fis = 17;     // pin A3  suono fischio filo nero - filo marrone gnd
const int pserv_sta = 6;      // pin D06 servo deviatoio stazione
const int pserv_mag = 7;      // pin D07 servo deviatoio magazzino

const int prele_seg = 9;      // pin D09 relè segnale
const int prele_cor = 8;      // pin D08 relè corente

const int pabi_mt1 = 10;      // pin D10 abilita motore
const int pava_mt1 = 11;      // pin D11 controllo motore
const int pind_mt1 = 12;      // pin D12 controllo motore

long t2 = 0;                  // variabile valore tempo stop
long tempo = 6000;            // tempo stop
long t1 = 0;                  // variabile pausa
long pau = 1500;              // tempo pausa 

int cnt_772 = 0;              // contatore corse littorina 772
int go_772 = 0;               // indicatore partenza 772
int cnt_kof = 1;              // contatore corse Kof
int go_kof = 0;               // indicatore partenza Kof
int vb = 95;                  // velocità partenza 772
int vm = 200;                 // velocità massima 772
int vk = 30;                  // velocità partenza Kof
int vj = 55;                  // velocità massima KOF
int va = 0;                   // velocità di corsa 772 e Kof
int sv = HIGH;                // salva variabile sensore velocità
int st = HIGH;                // salva variabile sensore stazione
int sf = HIGH;                // salva variabile sensore fine corsa
int sm = HIGH;                // salva variabile sensore magazzino
int cl = 3;                   // numero corse littorina Aln 772
int ck = 1;                   // numero corse Kof

void setup() {  // ------------- Inizializzazione Pin, sensori, relè e motori -----------------------

  // Serial.begin(9600);

  pinMode(pserv_sta, OUTPUT);    // pin output deviatoio stazione
  pinMode(pserv_mag, OUTPUT);    // pin output deviatoio magazzino

  pinMode(pvoic_cam, OUTPUT);    // pin output suono campanella
  pinMode(pvoic_par, OUTPUT);    // pin output suono partenza
  pinMode(pvoic_arr, OUTPUT);    // pin output suono arrivo
  pinMode(pvoic_fis, OUTPUT);    // pin output suono fischio

  pinMode(psens_sta, INPUT);     // pin input sensore stazione
  pinMode(psens_mag, INPUT);     // pin input sensore magazzino
  pinMode(psens_end, INPUT);     // pin input sensore fine corsa galleria
  pinMode(psens_seg, INPUT);     // pin input sensore segnale
  pinMode(psens_vel, INPUT);     // pin input sensore velocità

  pinMode(pabi_mt1, OUTPUT);     // pin output abilitazione motore
  pinMode(pava_mt1, OUTPUT);     // pin output controllo motore
  pinMode(pind_mt1, OUTPUT);     // pin output controllo motore

  pinMode(prele_seg, OUTPUT);    // pin coutput controllo relè segnale
  digitalWrite(prele_seg, LOW);  // segnale rosso 
  pinMode(prele_cor, OUTPUT);    // pin output controllo relè corrente binario

  digitalWrite(pava_mt1, LOW);   // ferma motore
  digitalWrite(pind_mt1, LOW);   // ferma motore
  digitalWrite(pabi_mt1, HIGH);  // accende motore

  digitalWrite(pserv_sta, LOW);  // deviatoio stazione
  digitalWrite(pserv_mag, LOW);  // deviatoio magazzino
  

} // ------------------------------ Fine inizializzazione ----------------------------------------

void loop() {   // --------------------------- Inizio esecuzione programma -----------------------

  while (cnt_772 < cl) {     // ----------- Inizio ciclo corse littorina Aln 772 -----------------

      switch (go_772) {

        case 0:        
          partenza772();
          break;

        case 1:
          corsa772();
          break;

        case 2:
          ritorno772();
          break;
      }

  } // ------------------------------------ Fine Ciclo Aln 772 -----------------------------------------------

  // --------------------------------------- Inizio ciclo KOF ------------------------------------------------

  if (cnt_kof < ck)  {                    // Inizio ciclo corse Kof

      switch (go_kof) {

        case 0:        
          partenzakof();
          break;

        case 1:
          corsakof();
          break;

        case 2:
          ritornokof();
          break;
      }
    
  } // ------------------------------------------ Fine Ciclo Kof -----------------------------------
  
} // --------------------------------------- Fine Esecuzione Programma -----------------------------

void partenza772() {
  digitalWrite(pvoic_par, HIGH);       // relè suono partenza
  delay(100);                          // ritardo
  digitalWrite(pvoic_par, LOW);        // relè suono partenza
  delay(15000);                        // ritardo
  digitalWrite(prele_seg, HIGH);       // relè segnale verde
  delay(100);                          // ritardo
  digitalWrite(pvoic_fis, HIGH);       // relè suono fischio
  delay(100);                          // ritardo                   
  digitalWrite(pvoic_fis, LOW);        // relè suono fischio     
  delay(1000);                         // ritardo
  digitalWrite(prele_cor, LOW);        // corrente binario 772
  delay(10);                           // ritardo
  analogWrite(pabi_mt1, vb);           // imposta velocità motore
  va = vb;                             // salva velocità iniziale
  digitalWrite(pava_mt1, LOW);         // avanti motore verso galleria
  digitalWrite(pind_mt1, HIGH);        // avanti motore verso galleria
  go_772 = 1;                          // variabile operativa corsa
  sv = HIGH;                           // variabile sensore velocità
  t1 = millis();                       // savla tempo
}

void corsa772() {
  int vseg = digitalRead(psens_seg);   // variabile sensore segnale
  delay(10);                           // ritardo
  if (vseg == LOW) {                   // sensore segnale
    digitalWrite(prele_seg, LOW);      // segnale rosso
    delay(10);                         // ritardo
  }
  if (va < vm) {                       // controllo accelerazione
    long dif = millis() - t1;          // calcolo tempo
      if (dif > pau) {                 // confronta tempo
        va = va + 12;                  // calcola velocità
        analogWrite(pabi_mt1, va);     // imposta velocità motore
        t1 = millis();                 // salva tempo;
      }     
  }
  int p772 = digitalRead(psens_end);  // variabile sensore fine corsa verso galleria
  delay(10);                          // ritardo
  if (p772 == LOW) {                  // sensore fine corsa
    delay(200);                       // ritardo
    digitalWrite(pava_mt1, LOW);      // ferma motore
    digitalWrite(pind_mt1, LOW);      // ferma motore
    va = vm;                          // velocità ritorno
    t2 = millis();                    // calcola tempo
    sf = p772;                        // variabile fine corsa 
  }     
  if (sf == LOW) { 
    long dif = millis() - t2;            // calcola tempo
    if (dif > tempo)  {                  // verifica tempo
      go_772 = 2;                        // variabile opertiva ritorno
      sf = HIGH;                         // variabile sensore fine corsa
      digitalWrite(pvoic_cam, HIGH);     // attiva suono campanella
      delay(100);                        // ritardo
      digitalWrite(pvoic_cam, LOW);      // attiva suono campanella
      delay(10);                         // ritardo    
      digitalWrite(pava_mt1, HIGH);      // ferma motore
      digitalWrite(pind_mt1, LOW);       // ferma motore  
      t1 = millis();                     // salva tempo
    } 
  }                  
}

void ritorno772() {
  int vvel = digitalRead(psens_vel);   // variabile sensore velocità
  delay(10);                           // ritardo
  if (vvel == LOW) {                   // sensore velocità
    digitalWrite(pvoic_cam, HIGH);     // ferma suono campanella
    delay(100);                        // ritardo
    digitalWrite(pvoic_cam, LOW);      // ferma suono campanella
    delay(1000);                       // ritardo          
    digitalWrite(pvoic_arr, HIGH);     // suono arrivo
    delay(100);                        // ritardo
    digitalWrite(pvoic_arr, LOW);      // suono arrivo
    delay(10);                         // ritardo 
    sv = vvel;                         // variable sensore velocità
  }
  if (sv == LOW)   {                     // controllo sensore velocità
    if (va > vb) {                       // decelerazione
      long dif = millis() - t1;          // calcolo tempo
      if (dif > pau) {                   // confronta tempo
        va = va - 12;                    // calcola velocità
        analogWrite(pabi_mt1, va);       // imposta velocità motore
        t1 = millis();                   // salva tempo
      }    
    }
  }
  int p772 = digitalRead(psens_sta);     // variabile sensore fine corsa stazione
  delay(10);                             // ritardo
  if (p772 == LOW) {                     // controllo sensore fine corsa
    delay(500);                          // sensore fine corsa verso stazione
    digitalWrite(pava_mt1, LOW);         // ferma motore
    digitalWrite(pind_mt1, LOW);         // ferma motore
    st = p772;                           // salva sensore fine corsa stazione
    t2 = millis();                       // tempo di fermata
  }
  if (st == LOW) {                       // sensore fine cors stazione
    long dif = millis() - t2;            // calcolo tempo
    if (dif > tempo) {                   // confronta tempo
      cnt_772 = cnt_772 + 1;             // incremento contatore corse 772
      st = HIGH;                         // ripristino variabile sensore fine corsa stazione
      if (cnt_772 == cl) {               // predispone partenza Kof
        cnt_kof = 0;                     // contatore corse Kof
        digitalWrite(pserv_sta, HIGH);   // predispone deviatoio stazione per Kof
        delay(10);                       // ritardo
        digitalWrite(pserv_mag, HIGH);   // predispone deviatoio magazzino per KOF
        delay(10);                       // ritardo
      }
      go_772 = 0;                        // indicatore partenza 772 da stazione
      sv = HIGH;                         // ripristino variabile sensore velocità
    }
  }
}

void partenzakof() {
  digitalWrite (pserv_mag, HIGH);      // deviatoio magazzino
  delay(10);                           // ritardo
  digitalWrite (pserv_sta, HIGH);      // deviatoio stazione
  delay(10);                           // ritardo
  digitalWrite(pvoic_par, HIGH);       // suono partenza
  delay(100);                          // ritardo
  digitalWrite(pvoic_par, LOW);        // suono partenza
  delay(15000);                        // ritardo
  digitalWrite(pvoic_fis, HIGH);       // suono fischio
  delay(100);                          // ritardo
  digitalWrite(pvoic_fis, LOW);        // suono fischio
  delay(10);                           // ritardo
  digitalWrite(prele_cor, HIGH);       // corrente binario Kof
  delay(10);                           // ritardo
  analogWrite(pabi_mt1, vb);           // imposta velocità motore
  va = vk;                             // salva velocità iniziale      
  digitalWrite(prele_cor, HIGH);       // corrente binario magazzino
  delay(10);                           // ritardo
  analogWrite(pabi_mt1, vk);           // imposta velocità motore
  digitalWrite(pava_mt1, LOW);         // avanti motore verso galleria
  digitalWrite(pind_mt1, HIGH);        // avanti motore verso galleria       
  go_kof = 1;                          // variabile operativa
  t1 = millis();                       // salva tempo
}

void corsakof()  {
  if (va < vj)  {                      // accelerazione
    long dif = millis() - t1;          // calcolo tempo
    if (dif > pau)  {                  // confronta tempo
      va = va + 5;                     // calcola velocità
      analogWrite(pabi_mt1, va);       // imposta velocità motore
    }
  }
  int vvel = digitalRead(psens_vel);   // variabile sensore velocità
  delay(10);                           // ritardo
  if (vvel == LOW) {                   // sensore velocità
    digitalWrite(pserv_sta, LOW);      // predispone deviatoio stazione
    delay(10);                         // ritardo
    digitalWrite(pserv_mag, LOW);      // predispone deviatoio magazzino
  }
  int p772 = digitalRead(psens_end);    // variabile sensore fine corsa verso galleria
  delay(10);                            // ritardo
  if (p772 == LOW) {                    // sensore fine corsa
    delay(200);                         // ritardo
    digitalWrite(pava_mt1, LOW);        // ferma motore
    digitalWrite(pind_mt1, LOW);        // ferma motore
    va = vj;                            // velocità ritorno
    t2 = millis();                      // calcola tempo
    sf = p772;                          // salva variabile fine corsa
    t1 = millis();                      // salva tempo
  }
  if (sf == LOW) { 
    long dif = millis() - t2;            // calcola tempo
    if (dif > tempo)  {                  // verifica tempo
      go_kof = 2;                        // variabile opertiva ritorno
      sf = HIGH;                         // variabile sensore fine corsa 
      digitalWrite(pvoic_cam, HIGH);     // ferma suono campanella
      delay(100);                        // ritardo
      digitalWrite(pvoic_cam, LOW);      // ferma suono campanella
      delay(10);                         // ritardo    
      digitalWrite(pava_mt1, HIGH);      // ferma motore
      digitalWrite(pind_mt1, LOW);       // ferma motore  
      t1 = millis();                     // salva tempo
    } 
  }   
}

void ritornokof() {
  int vvel = digitalRead(psens_vel);   // variabile sensore velocità
  delay(10);                           // ritardo
  if (vvel == LOW) {                   // sensore velocità
    digitalWrite(pserv_sta, HIGH);     // predispone deviatoio stazione
    delay(10);                         // ritardo
    digitalWrite(pserv_mag, HIGH);     // predispone deviatoio magazzino
    delay(10);                         // ritardo 
    digitalWrite(pvoic_cam, HIGH);     // ferma suono campanella
    delay(100);                        // ritardo
    digitalWrite(pvoic_cam, LOW);      // ferma suono campanella
    delay(1000);                       // ritardo          
    digitalWrite(pvoic_arr, HIGH);     // suono arrivo
    delay(100);                        // ritardo
    digitalWrite(pvoic_arr, LOW);      // suono arrivo
    delay(10);                         // ritardo
    sv = vvel;                         // variable sensore velocità
  }
  if (sv == LOW)   {                     // controllo sensore velocità
    if (va > vk) {                       // decelerazione
      long dif = millis() - t1;          // calcolo tempo
      if (dif > pau) {                   // confronta tempo
        va = va - 5;                     // calcola velocità
        analogWrite(pabi_mt1, va);       // imposta velocità motore
        t1 = millis();                   // salva tempo
      }    
    }
  }
  int pkof = digitalRead(psens_mag);     // variabile sensore fine corsa magazzino
  delay(10);                             // ritardo
  if (pkof == LOW) {                     // sensore fine vorsa
    delay(200);                          // sensore fine corsa verso stazione
    digitalWrite(pava_mt1, LOW);         // ferma motore
    digitalWrite(pind_mt1, LOW);         // ferma motore
    digitalWrite(pserv_sta, LOW);        // predispone deviatoio stazione
    delay(10);                           // ritardo
    digitalWrite(pserv_mag, LOW);        // predispone deviatoio magazzino
    delay(10);                           // ritardo
    sm = pkof;                           // variabile sensore magazzino 
    t2 = millis();                       // tempo di fermata
  }
  if (sm == LOW) {                       // sensore fine corsa stazione
    long dif = millis() - t2;            // calcolo tempo
    if (dif > tempo) {                   // confronta tempo
      cnt_kof = 1;                       // incremento contatore corse Kof
      cnt_772 = 0;                       // contatore corse 772
      go_772 = 0;                        // indicatore partenza 772 da stazione;           
      go_kof = 0;                        // inficatore partenza Kof
      sm = HIGH;                         // variabile sensore magazzino 
      sv = HIGH;                         // sensore velocità              
    }
  }
    
}

